+7-960-0655211 (Билайн)
+7-987-4207734 (МТС)

интернет-магазин
доставка по России и СНГ
работаем с 2010 года

Робот BURN-E из бумаги и "радар" на ультразвуковом дальномере

Робот BURN-E из бумаги и "радар" на ультразвуковом дальномере

 01.jpg

В этом обучающем проекте будет показано, как из бумаги сделать красивый корпус робота с подвижными элементами, а на основе данных с ультразвукового дальномера красивую визуализацию.

Для этого проекта понадобиться:

  • плотная бумага или картон
  • плата Arduino
  • ультразвуковой дальномер (HC-SR04 или подобный)
  • сервопривод для вращения головы, дополнительно можете использовать ещё два для рук
  • макетная плата
  • соединительные провода

Схема подключения

02.jpg
 

Ультразвуковой датчик HC-SR04 подключен к выводам 10 и 11, а сервопривод к выводу 12 платы Arduino. Если будете подключать к другим выводам, не забудьте сделать соответствующие поправки в коде.

Питание сервопривода для теста взято с платы Arduino, но лучше даже с одним маломощным сервоприводом использовать внешнее дополнительное питание - из-за проседания питания или помех по цепи питания может работать не стабильно. Если вместо маломощного сервопривода (типоразмер микро) будете использовать более мощные (к примеру "стандартного" типоразмера) или вместо одного будете использовать три сервопривода (ещё два для рук), настоятельно рекомендуется использовать дополнительный источник питания. В противном случае Arduino может выйти из строя.

Электронику можно собрать сразу в корпусе робота или если будет удобней, то предварительно на макетной плате. Во втором случае дальномер можно закрепить на качалке сервопривода с помощью клеевого пистолета примерно так:

 03.jpg

Код для Arduino

// Includes the Servo library
#include <Servo.h>.
// Defines Tirg and Echo pins of the Ultrasonic Sensor
const int trigPin = 10;
const int echoPin = 11;
// Variables for the duration and the distance
long duration;
int distance;
Servo myServo; // Creates a servo object for controlling the servo motor
void setup() {
  pinMode(trigPin, OUTPUT); // Sets the trigPin as an Output
  pinMode(echoPin, INPUT); // Sets the echoPin as an Input
  Serial.begin(9600);
  myServo.attach(12); // Defines on which pin is the servo motor attached
}
void loop() {
  // rotates the servo motor from 15 to 165 degrees
  for (int i = 15; i <= 165; i++) {
    myServo.write(i);
    delay(30);
    distance = calculateDistance();// Calls a function for calculating the distance measured by the Ultrasonic sensor for each degree

    Serial.print(i); // Sends the current degree into the Serial Port
    Serial.print(","); // Sends addition character right next to the previous value needed later in the Processing IDE for indexing
    Serial.print(distance); // Sends the distance value into the Serial Port
    Serial.print("."); // Sends addition character right next to the previous value needed later in the Processing IDE for indexing
  }
  // Repeats the previous lines from 165 to 15 degrees
  for (int i = 165; i > 15; i--) {
    myServo.write(i);
    delay(30);
    distance = calculateDistance();
    Serial.print(i);
    Serial.print(",");
    Serial.print(distance);
    Serial.print(".");
  }
}
// Function for calculating the distance measured by the Ultrasonic sensor
int calculateDistance() {

  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  // Sets the trigPin on HIGH state for 10 micro seconds
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);
  duration = pulseIn(echoPin, HIGH); // Reads the echoPin, returns the sound wave travel time in microseconds
  distance = duration * 0.034 / 2;
  return distance;
}

Скопируйте код скетча BurnE_arduino.ino в Arduino Ide и загрузите его в плату. Не забудьте в настройках выбрать свою плату и com-порт, к которому она подключена.

В этом коде циклически (сначала в одну сторону, затем в другую) сервопривод проворачивается на определённый угол, затем с дальномера считываются данные, вычисляется расстояние и данные об угле и расстоянии отправляются в последовательный порт.

Код для Processing

Скопируйте следующий код скетча BurnE_arduino.ino в Processing:


import processing.serial.*;
import java.awt.event.KeyEvent;
import java.io.IOException;

Serial myPort;

String angle="";
String distance="";
String data="";
String noObject;
float pixsDistance;
int iAngle, iDistance;
int index1=0;
int index2=0;
PFont orcFont;

void setup()
{
  size (1920, 1080); // ***CHANGE THIS TO YOUR SCREEN RESOLUTION***
  smooth();
  myPort = new Serial(this, "COM1", 9600); // starts the serial communication
  myPort.bufferUntil('.'); // reads the data from the serial port up to the character '.'. So actually it reads this: angle,distance.
}

void draw()
{
  fill(98, 245, 31);
  // simulating motion blur and slow fade of the moving line
  noStroke();
  fill(0, 4); 
  rect(0, 0, width, height-height*0.065); 

  fill(98, 245, 31); // green color
  // calls the functions for drawing the radar
  drawRadar(); 
  drawLine();
  drawObject();
  drawText();
}

void serialEvent (Serial myPort)
{
  // starts reading data from the Serial Port
  // reads the data from the Serial Port up to the character '.' and puts it into the String variable "data".
  data = myPort.readStringUntil('.');
  data = data.substring(0, data.length()-1);

  index1 = data.indexOf(","); // find the character ',' and puts it into the variable "index1"
  angle= data.substring(0, index1); // read the data from position "0" to position of the variable index1 or thats the value of the angle the Arduino Board sent into the Serial Port
  distance= data.substring(index1+1, data.length()); // read the data from position "index1" to the end of the data pr thats the value of the distance

  // converts the String variables into Integer
  iAngle = int(angle);
  iDistance = int(distance);
}

void drawRadar()
{
  pushMatrix();
  translate(width/2, height-height*0.074); // moves the starting coordinats to new location
  noFill();
  strokeWeight(2);
  stroke(98, 245, 31);
  // draws the arc lines
  arc(0, 0, (width-width*0.0625), (width-width*0.0625), PI, TWO_PI);
  arc(0, 0, (width-width*0.27), (width-width*0.27), PI, TWO_PI);
  arc(0, 0, (width-width*0.479), (width-width*0.479), PI, TWO_PI);
  arc(0, 0, (width-width*0.687), (width-width*0.687), PI, TWO_PI);
  // draws the angle lines
  line(-width/2, 0, width/2, 0);
  line(0, 0, (-width/2)*cos(radians(30)), (-width/2)*sin(radians(30)));
  line(0, 0, (-width/2)*cos(radians(60)), (-width/2)*sin(radians(60)));
  line(0, 0, (-width/2)*cos(radians(90)), (-width/2)*sin(radians(90)));
  line(0, 0, (-width/2)*cos(radians(120)), (-width/2)*sin(radians(120)));
  line(0, 0, (-width/2)*cos(radians(150)), (-width/2)*sin(radians(150)));
  line((-width/2)*cos(radians(30)), 0, width/2, 0);
  popMatrix();
}

void drawObject()
{
  pushMatrix();
  translate(width/2, height-height*0.074); // moves the starting coordinats to new location
  strokeWeight(9);
  stroke(255, 10, 10); // red color
  pixsDistance = iDistance*((height-height*0.1666)*0.025); // covers the distance from the sensor from cm to pixels
  // limiting the range to 40 cms
  if (iDistance<40) {
    // draws the object according to the angle and the distance
    line(pixsDistance*cos(radians(iAngle)), -pixsDistance*sin(radians(iAngle)), (width-width*0.505)*cos(radians(iAngle)), -(width-width*0.505)*sin(radians(iAngle)));
  }
  popMatrix();
}

void drawLine()
{
  pushMatrix();
  strokeWeight(9);
  stroke(30, 250, 60);
  translate(width/2, height-height*0.074); // moves the starting coordinats to new location
  line(0, 0, (height-height*0.12)*cos(radians(iAngle)), -(height-height*0.12)*sin(radians(iAngle))); // draws the line according to the angle
  popMatrix();
}

void drawText()
{
  // draws the texts on the screen

  pushMatrix();
  if (iDistance>40) {
    noObject = "Out of Range";
  } else {
    noObject = "In Range";
  }
  fill(0, 0, 0);
  noStroke();
  rect(0, height-height*0.0648, width, height);
  fill(98, 245, 31);
  textSize(25);

  text("10cm", width-width*0.3854, height-height*0.0833);
  text("20cm", width-width*0.281, height-height*0.0833);
  text("30cm", width-width*0.177, height-height*0.0833);
  text("40cm", width-width*0.0729, height-height*0.0833);
  textSize(40);
  text("Object: " + noObject, width-width*0.875, height-height*0.0277);
  text("Angle: " + iAngle +" ", width-width*0.48, height-height*0.0277);
  text("Distance: ", width-width*0.26, height-height*0.0277);
  if (iDistance<40) {
    text("        " + iDistance +" cm", width-width*0.225, height-height*0.0277);
  }
  textSize(25);
  fill(98, 245, 60);
  translate((width-width*0.4994)+width/2*cos(radians(30)), (height-height*0.0907)-width/2*sin(radians(30)));
  rotate(-radians(-60));
  text("30", 0, 0);
  resetMatrix();
  translate((width-width*0.503)+width/2*cos(radians(60)), (height-height*0.0888)-width/2*sin(radians(60)));
  rotate(-radians(-30));
  text("60", 0, 0);
  resetMatrix();
  translate((width-width*0.507)+width/2*cos(radians(90)), (height-height*0.0833)-width/2*sin(radians(90)));
  rotate(radians(0));
  text("90", 0, 0);
  resetMatrix();
  translate(width-width*0.513+width/2*cos(radians(120)), (height-height*0.07129)-width/2*sin(radians(120)));
  rotate(radians(-30));
  text("120", 0, 0);
  resetMatrix();
  translate((width-width*0.5104)+width/2*cos(radians(150)), (height-height*0.0574)-width/2*sin(radians(150)));
  rotate(radians(-60));
  text("150", 0, 0);
  popMatrix();
}

Подключенная плата Arduino отправляет данные, которые считываются из последовательного порта с помощью функции SerialEvent и заносятся в переменные угла и расстояния (iAngle и iDistance). Эти переменные будут использоваться для рисования линий, обнаруженных объектов и текста нашего "радара".

В функции setup есть строки:

size (1920, 1080);
myPort = new Serial(this, "COM1", 9600);

В них настраивается размер окна, в котором отрисовывается "радар" и Com-порт, к которому подключена Arduino и битрейт (если будете использовать другой, не забудьте изменить и в скетче Arduino).

 04.jpg

В drawRadar функциями arc и line отрисовываются линии и дуги.

 05.jpg

Движущаяся линия отрисовывается в функции drawLine. Центр вращения устанавливается с помощью функции translate, а с помощью функции line отрисовывается линия для нужного угла.

 06.jpg

Функция drawObject используется для отрисовки обнаруженного препятствия с учётом расстояния.

Отрисовка текста производится в функции drawText.

Все эти функции вызываются в основной функции draw. Для имитации эффекта размытия и медленного угасания движущейся линии используется функция fill.

Вот окончательный вид радара:

 07.jpg

Корпус

 08.jpg

Модель реплики BURN-E можно скачать по следующей ссылке или по альтернативной ссылке (актуальный пароль к PDF файлу там указан внизу страницы).

09.jpg

10.jpg

11.jpg

12.jpg

13.jpg

14.jpg

15.jpg

Руки можно прикрепить на прямую к корпусу. Если захочется что бы кроме головы двигались и руки, можно добавить на каждую по сервоприводу. Внутри руки закрепляется качалка:

16.jpg

17.jpg


Внутри корпуса сервоприводы:


18.jpg